REGEDIT4
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon]
"DefaultUserName"=""
"DefaultDomainName"="<domain-name-here>"

 
regedit /s \\<server>\eXpress\<filename>.reg

' Reset Default Logon to most Receintly Accessed Profile
'vbscript

'** Written by:
'**  Dane Jones
'** Description: 
'**  This script will reset the default logon screen to display the most reciently access profile/user.  
'**  This was written for remote administrators to be able to quickly reset the logon after loggin on as the Administrator.
'**  You can add additional accounts to ignore on line 74.

'** Define Variables
    Dim WshShell' As WScript.Shell
    Dim UserName' As String
    Dim IsVerbose_STATIC' As Boolean
    
'** Declare Constants
    Const KeyPath = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\"' As String
    Const DomainName = "<YourDomain>"
    
'** Create Objects
    Set WshShell = CreateObject("WScript.Shell")

'** Guess the User's Name
    UserName = GuessName

'** Display Dialog
    If IsVerbose Then _
        UserName = InputBox("Please enter username.", "Logon Reset", UserName)

If UserName = "" Then WScript.Quit 1

'** Set User Name
    WshShell.RegWrite KeyPath & "AltDefaultUserName", UserName, "REG_SZ"
    WshShell.RegWrite KeyPath & "DefaultUserName", UserName, "REG_SZ"

'** Set Domain
    WshShell.RegWrite KeyPath & "AltDefaultDomainName", DomainName, "REG_SZ"
    WshShell.RegWrite KeyPath & "DefaultDomainName", DomainName, "REG_SZ"

'** Hide Logon Options
    WshShell.RegWrite KeyPath & "ShowLogonOptions", 0, "REG_DWORD"

'** Close
    If IsVerbose Then _
         MsgBox "User's Domain Information Set",,"Logon Reset"

'** Function to Guess User Name
    Function GuessName()' As String
        Dim fso' As Scripting.FileSystemObject
        Dim Profiles' As SubFolders
        Dim Profile' As Folder
        Dim Candidate' As Array
        Dim NTUserDate' As Date
        
        Const NTUSerDAT_Name = "NTUSER.DAT"' As String
        Const ProfilePath = "C:\Documents and Settings\"' As String
        
        Set fso = CreateObject("Scripting.FileSystemObject")
        
        If Not fso.FolderExists(ProfilePath) Then
            GuessName = ""
            Exit Function
        End If
        
        Set Profiles = fso.GetFolder(ProfilePath).SubFolders
        
        '** Define Candidate Structure
            Candidate = Array(DateValue("Jan 1, 1980"), "")
        
        '** Search Profiles
            For Each Profile In Profiles
                Select Case UCase(Profile.Name)
                    '** Ignore Special Accounts
                    Case "ADMINISTRATOR", "ALL USERS", "DEFAULT USER", "LOCALSERVICE", "NETWORKSERVICE"
                        '** Do Nothing
                    Case Else
                        NTUserDate = Profile.Files(NTUSerDAT_Name).DateLastModified
                        'Set NTUserDAT = Profile.Files(NTUSerDAT_Name)
                        If NTUserDate > Candidate(0) Then
                            Candidate(0) = NTUserDate
                            Candidate(1) = Left(UCase(Profile.Name), 2) & Mid(Replace(LCase(Profile.Name),"." & LCase(DomainName),""), 3)
                        End If
                End Select
            Next
            
        '** Return Guess
            Debug.WriteLine "Guessed Name: " & Candidate(1)
            GuessName = Candidate(1)
    End Function
    
'** Process Any Command Line Switches
    Function IsVerbose()' As Boolean
        If IsEmpty(IsVerbose_STATIC) Then
            IsVerbose_STATIC = False
            If WScript.Arguments.Count > 0 Then _
                If UCase(WScript.Arguments.Item(0)) = "-V" Then _
                    IsVerbose_STATIC = True
        End If
        IsVerbose = IsVerbose_STATIC
    End Function